Reorganize the tree, have better ifw.pri. Shadow build support.

Change-Id: I01fb12537f863ed0744979973c7e4153889cc5cb
Reviewed-by: Tim Jenssen <tim.jenssen@nokia.com>

examples/downloadspeed/downloadspeed.pro

@@ -1,14 +0,0 @@
-include(../../installerbuilder/libinstaller/libinstaller.pri)
-DEPENDPATH += . .. ../../installerbuilder/libinstaller
-INCLUDEPATH += . .. ../../installerbuilder/libinstaller
-
-TEMPLATE = app
-CONFIG += console
-CONFIG -= app_bundle
-TARGET = downloadspeed
-
-QT -= gui
-QT += core network
-LIBS = -L$$OUT_PWD/../../installerbuilder/lib -linstaller $$LIBS
-
-SOURCES += main.cpp

examples/examples.pro

@@ -1,3 +1,3 @@
-TEMPLATE = subdirs
 CONFIG += ordered
-SUBDIRS += testapp downloadspeed
+TEMPLATE = subdirs
+SUBDIRS += testapp

examples/testapp/testapp.pro

@@ -1,33 +1,38 @@
 TEMPLATE = app
-TARGET =
+DEPENDPATH += . ..
+INCLUDEPATH += . ..
+TARGET = testapp
 
-include( ../../installerbuilder/libinstaller/libinstaller.pri )
-LIBS = -L$$OUT_PWD/../../installerbuilder/lib -linstaller $$LIBS
+include(../../installerfw.pri)
 
-DESTDIR = packages/com.nokia.testapp/data
-
-QT += script network xml sql
-CONFIG += uitools help
-contains(CONFIG, static): {
-    QTPLUGIN += qsqlite
-    DEFINES += USE_STATIC_SQLITE_PLUGIN
+!static {
+    warning("You can use this example only with a static build of Qt and IFW!")
 }
 
-# Input
-FORMS += componentselectiondialog.ui updatesettingsdialog.ui updatesettingswidget.ui
-HEADERS += mainwindow.h \
-    componentselectiondialog.h \
-    updatesettingsdialog.h \
-    updateagent.h \
-    updatesettingswidget.h
+LIBS += -linstaller
+DESTDIR = packages/com.nokia.testapp/data
 
-SOURCES += main.cpp mainwindow.cpp \
-    componentselectiondialog.cpp \
-    updatesettingsdialog.cpp \
-    updateagent.cpp \
-    updatesettingswidget.cpp
+FORMS += \
+        componentselectiondialog.ui \
+        updatesettingsdialog.ui \
+        updatesettingswidget.ui
+
+HEADERS += mainwindow.h \
+        componentselectiondialog.h \
+        updatesettingsdialog.h \
+        updateagent.h \
+        updatesettingswidget.h
+
+SOURCES += main.cpp \
+        mainwindow.cpp \
+        componentselectiondialog.cpp \
+        updatesettingsdialog.cpp \
+        updateagent.cpp \
+        updatesettingswidget.cpp
 
 RESOURCES += testapp.qrc
 
-macx:QMAKE_POST_LINK = ($$OUT_PWD/../../installerbuilder/bin/binarycreator -p packages -c config -t ../../installerbuilder/bin/installerbase TestAppInstaller.app com.nokia.testapp)
-win32:QMAKE_POST_LINK = ($$OUT_PWD\\..\\..\\installerbuilder\\bin\\binarycreator.exe -p $$PWD\\packages -c $$PWD\\config -t $$OUT_PWD\\..\\..\\installerbuilder\\bin\\installerbase.exe TestAppInstaller.exe com.nokia.testapp)
+isEqual(IFW_SOURCE_TREE, $$IFW_BUILD_TREE) {
+    macx:QMAKE_POST_LINK = ($$IFW_APP_PATH/binarycreator -p $$PWD/packages -c $$PWD/config -t $$IFW_APP_PATH/installerbase TestAppInstaller.app com.nokia.testapp)
+    win32:QMAKE_POST_LINK = ($$IFW_APP_PATH/binarycreator.exe -p $$PWD/packages -c $$PWD/config -t $$IFW_APP_PATH/installerbase.exe TestAppInstaller.exe com.nokia.testapp)
+}

installerbuilder/installerbuilder.pro

@@ -1,4 +0,0 @@
-TEMPLATE = subdirs
-CONFIG += ordered
-SUBDIRS += libinstaller installerbase binarycreator repogen archivegen
-TRANSLATIONS += installerbase/translations/de_de.ts installerbase/translations/en_us.ts

installerbuilder/libinstaller/libinstaller.pri

@@ -1,45 +0,0 @@
-macx:DEFINES += _LZMA_UINT32_IS_ULONG
-
-DEFINES += FSENGINE_TCP
-
-INCLUDEPATH += $$PWD \
-    $$PWD/.. \
-    $$PWD/3rdparty/kdtools \
-    $$PWD/3rdparty/7zip \
-    $$PWD/3rdparty/7zip/unix/CPP
-
-DEPENDPATH += $$PWD \
-    $$PWD/.. \
-    $$PWD/3rdparty/kdtools \
-    $$PWD/3rdparty/7zip \
-    $$PWD/3rdparty/7zip/unix/CPP
-
-CONFIG( shared, static|shared ):DEFINES += LIB_INSTALLER_SHARED
-CONFIG( shared, static|shared ):DEFINES += KDTOOLS_SHARED
-
-CONFIG += uitools help
-
-contains(CONFIG, static): {
-    QTPLUGIN += qsqlite
-    DEFINES += USE_STATIC_SQLITE_PLUGIN
-}
-
-QT += script
-QT += gui # gui needed for KDUpdater include (compareVersion), which indirectly include QTreeWidget
-
-LIBS = -L$$OUT_PWD/../lib -L$$OUT_PWD/../../lib -linstaller $$LIBS
-
-macx:LIBS += -framework Security
-unix:!macx:LIBS += -lutil
-
-static {
-    unix {
-        exists($$OUT_PWD/../lib/libinstaller.a):POST_TARGETDEPS += $$OUT_PWD/../lib/libinstaller.a
-        exists($$OUT_PWD/../../lib/libinstaller.a):POST_TARGETDEPS += $$OUT_PWD/../../lib/libinstaller.a
-    }
-    win32 {
-        exists($$OUT_PWD/../lib/installer.lib):POST_TARGETDEPS += $$OUT_PWD/../lib/installer.lib
-        exists($$OUT_PWD/../../lib/installer.lib):POST_TARGETDEPS += $$OUT_PWD/../../lib/installer.lib
-    }
-}
-

installerfw.pri

@@ -0,0 +1,57 @@
+!isEmpty(IFW_PRI_INCLUDED) {
+    error("installerfw.pri already included")
+}
+IFW_PRI_INCLUDED = 1
+
+defineReplace(cleanPath) {
+    win32:1 ~= s|\\\\|/|g
+    contains(1, ^/.*):pfx = /
+    else:pfx =
+    segs = $$split(1, /)
+    out =
+    for(seg, segs) {
+        equals(seg, ..):out = $$member(out, 0, -2)
+        else:!equals(seg, .):out += $$seg
+    }
+    return($$join(out, /, $$pfx))
+}
+
+isEmpty(IFW_BUILD_TREE) {
+    sub_dir = $$_PRO_FILE_PWD_
+    sub_dir ~= s,^$$re_escape($$PWD),,
+    IFW_BUILD_TREE = $$cleanPath($$OUT_PWD)
+    IFW_BUILD_TREE ~= s,$$re_escape($$sub_dir)$,,
+}
+
+IFW_SOURCE_TREE = $$PWD
+IFW_APP_PATH = $$IFW_BUILD_TREE/bin
+IFW_LIB_PATH = $$IFW_BUILD_TREE/lib
+
+INCLUDEPATH += \
+    $$IFW_SOURCE_TREE/src/libs/7zip \
+    $$IFW_SOURCE_TREE/src/libs/kdtools \
+    $$IFW_SOURCE_TREE/src/libs/installer
+win32:INCLUDEPATH += $$IFW_SOURCE_TREE/src/libs/7zip/win/CPP
+unix:INCLUDEPATH += $$IFW_SOURCE_TREE/src/libs/7zip/unix/CPP
+
+LIBS += -L$$IFW_LIB_PATH
+unix:!macx:LIBS += -lutil
+macx:LIBS += -framework Carbon -framework Security
+
+CONFIG += help uitools
+CONFIG(static, static|shared) {
+    QTPLUGIN += qsqlite
+    QT += script network xml
+    DEFINES += USE_STATIC_SQLITE_PLUGIN
+}
+
+GIT_SHA1 = $$system(git rev-list --abbrev-commit -n1 HEAD)
+DEFINES += QT_NO_CAST_FROM_ASCII "_GIT_SHA1_=$$GIT_SHA1"
+
+CONFIG(shared, static|shared):DEFINES += KDTOOLS_SHARED
+CONFIG(shared, static|shared):DEFINES += LIB_INSTALLER_SHARED
+
+static {
+    win32:exists($$IFW_LIB_PATH/installer.lib):POST_TARGETDEPS += $$IFW_LIB_PATH/installer.lib
+    unix:exists($$IFW_LIB_PATH/libinstaller.a):POST_TARGETDEPS += $$IFW_LIB_PATH/libinstaller.a
+}

installerfw.pro

@@ -1,6 +1,6 @@
 CONFIG += ordered
 TEMPLATE = subdirs
-SUBDIRS += installerbuilder tools
+SUBDIRS += src tools
 !macx:SUBDIRS += examples
 
 test.target = test

src/libs/7zip/7zip.pri

@@ -1,9 +1,4 @@
 7ZIP_BASE=$$PWD
 
-SOURCES += $$7ZIP_BASE/lib7z_facade.cpp
-HEADERS += $$7ZIP_BASE/lib7z_facade.h
-
-INCLUDEPATH += $$7ZIP_BASE
-
-unix:include($$7ZIP_BASE/unix/unix.pri) #this is p7zip
 win32:include($$7ZIP_BASE/win/win.pri) #this is 7zip
+unix:include($$7ZIP_BASE/unix/unix.pri) #this is p7zip